
APGrph1: Example GPLOT with two vertical axes and various “improvements”

Prepared by Wendy Bergerud

Last Saved: 30 October 2003
This annotated program will walk you through the SAS code to produce the following graph.  The graph has two descending smooth curves obtained by using splines.  The points are plotted with filled dots using the scale on the left axis.  There is also one ascending curve without the points plotted but the points have been connected with a set of straight lines.  This ascending curve uses the scale on the right axis.  Horizontal reference lines have been placed at 0, 10, 80, 90 and 100% of the left vertical scale while vertical reference lines have been placed at 700 and 1200 wsph along the horizontal axis.  This graph has no legends and I will mention some options for adding them after discussing the whole program.

The full program without annotations is listed at the end of this note.  The data is in a dataset called graph.  There are three dependent variables: y1, y2 and y3 and one independent variable: x.  The data are sorted by x so that the spline fitting routine (that which makes the smooth descending curve in the above graph) will find the data in proper order and so produce a “nice” curve.

proc sort data=graph; by x;  run;

First we set up the parameters for the graph. The graphing options (goptions) are reset to default values so that past settings won’t interfere with current work.

goptions reset all;

Now set up parameters for producing CGM files.  These import
 nicely into both WORD and PowerPoint.

*** Goptions For CGM files;
goptions HSIZE=6.4   VSIZE=4.0   rotate=landscape

         hpos =128   vpos= 80    htitle=2.8  htext=2.0   hby=1.0
         chartype=5 ctext=black  csymbol=black   

         device=cgmof97L   gsfname=graph   gsfmode=replace; 

The first two options of the first line sets the horizontal and vertical size (default units are inches) of the graph.  The third option sets the graph to be produced in landscape mode.

The second line sets the number of positions in the horizontal and vertical directions thus defining the ‘cell size’ of the graph.  I like to use 20 cells per inch.  The next three options set the size or height of the title, text and by statements.  The default values are 2 cells for the title and one cell for everything else.

The third line sets the font as Times-Roman for text (the specific value used here depends upon the device driver selected).  The default colour of the text is set to black as well as for any symbols.

The last line sets the output device for the graph to cgmof97L, which produces a landscape cgm file (the “L” at the end is for landscape, you can use a “P” instead for portrait).  The gsfname points to a filename statement where the final graph is to be stored while the gsfmode specifies whether the graph replaces what was already in that file or appends the graph to that file.

The filename statement can be placed anywhere before the end of the PROC GPLOT statements.  I put it here to show how it looks.  The graph will be placed in a file called test.cgm in your current working directory (shown at the bottom of the SAS windows).

Now I code up the axes that I want in my graph.  I can leave these out and still get a nice graph. 

*** Vertical Axes; 

  axis1 label = (A=90 h=2.8 "% NSR Decisions") w=4
    order = 0 to 100 by 10 minor = none color = black;

  axis2 label = (A=270 h=2.8 "Projected Volume (m3/ha)") w=4
    order = 0 to 280 by 20 minor = none color = black;

*** Horizontal Axis;
  axis3 label = (h=2.8 "Well-spaced Density (wsph) at MITD of 2.0 m")

    order = 0 to 1600 BY 200  minor = none w=4 color = black ;

The label option describes the text for the axis label.  The height is specified by h=2.8.  The baseline for the text can be set to be parallel with an axis.  For the first vertical axis an angle is set at 90( by A=90, while for the second vertical axis the angle is set at A=270.

The width of the axis line is set by w=4.  The default value is w=1.

The major tick marks along the axis are specified by order=, and the minor ticks are removed from the plot by minor = none.

All colours are set to black by color = black or by c = black.

Now I set up the symbols and lines used to plot the data.

*** Plotting Symbols;
symbol1  v=dot   h=1.5  l=1    i=splines   w=5   c=green; 

symbol2  v=dot   h=1.5  l=22   i=splines   w=5   c=red;

symbol3  v=none         l=1    i=join      w=5   c=black;

Each statement is numbered so that we can choose where each symbol statement is used in the plot.  The first two statements are used for the smooth curves using the left vertical axis while the third is used for the jointed line plotted using the right vertical axis.  

The first symbol statement specifies that the value (v) or plotting symbol will be a filled dot.  The size (or height, h) of the symbol will be 1.5 instead of the default size of 1.0.  The line type will be 1 (there are 46 line types to choose from).  The points will be interpolated using a spline fit after sorting the value along the x-axis – since we have already done that we could have used i=spline instead.  The width of the line (w) will be 5 units instead of the default of 1.0.  The colour of the points and the line will be green.

The second symbol statement uses a different line type and colour from the first one.  The third symbol statement specifies that no symbol be plotted at the data points, that the points will be joined by straight line segments and that the colour will be black.

The next two statements specify that a blank title and a footnote be used in the graph.  Extra space at the top and bottom will be set aside for these.  These statements simply create some “white” space around the graph within the cgm file itself and are unnecessary.

title "   "; footnote "   ";  

Now we finally specify the graph we want using the gplot procedure.  

*** Specifying the graph;
proc gplot data=graph; 

  plot y1*x = 1 y2*x = 2 / overlay vaxis=axis1 haxis=axis3 

     vref=0, 10, 80, 90, 100  href=700, 1200 chref=gray88 cvref=gray88; 

  plot2 y3*x = 3 / vaxis=axis2  ; 

run; quit;

We call gplot and tell it to use the data in a dataset called graph.  The plot statement says to plot y1 against x using the symbols defined in the symbol1 statement (note the ‘1’ after the ‘=’), and to plot y2 against x using the symbol2 statement.  The overlay option puts these two plots on the same graph.  The vaxis option specifies which axis statement to use along the vertical axis, while the haxis does the same for the horizontal axis.  The vref option lists the values along the vertical axis for which horizontal lines will be placed.  The href option lists the values along the horizontal axis for which vertical lines will be drawn.  The chref and cvref options specifies the colours to be used for these reference lines.

The plot2 statement describes the second graph to be placed on the same graph but now using the right hand vertical axis.  The statements says to plot y3 against x using the symbol3 statement for the plotting symbols.  The vaxis option specifies that the axis3 statement be used to draw the right hand axis.

This procedure is finished with a run and a quit statement.  The quit statement completely ends the gplot procedure and frees the file specified in the filename statement so that it can be used again.

Adding legends

There are several ways that we can add legends or descriptive text to a graph:

1) If we had used a plot statement like:  plot y1*x = z,  where z is a third variable with a small number of values to denote the separate lines and identify the appropriate symbol statements, then SAS would have automatically generated a legend.

2) We could use a legend statement, which is similar to the axis and symbol statements used in this example.  There are extensive options available for this statement.  

3) We could use an annotate SAS data set to place a legend or  arrows and descriptive text right on the graph.  This method is also very flexible but takes some work to learn and fine-tune.

4) We could edit the graph in the SAS graphical editor.  This method is somewhat cumbersome yet.

5) We could import the graph into WORD and/or PowerPoint and use the ability of this software to add a legend or to overlay descriptive text with arrows pointing to the relevant curves.

Appendix: Complete Program 
/** Proc Gplot Example using the CGM driver for WORD and PowerPoint **/
proc sort data=graph; by x;  run;

goptions reset all;

*** Goptions For CGM files;
goptions HSIZE=6.4   VSIZE=4.0   rotate=landscape

         hpos =128   vpos= 80    htitle=2.8  htext=2.0   hby=1.0
         chartype=5 ctext=black  csymbol=black   

         device=cgmof97L   gsfname=graph   gsfmode=replace;

*** Vertical Axes; 

  axis1 label = (A=90 h=2.8 "% NSR Decisions") w=4
    order = 0 to 100 by 10 minor = none color = black;

  axis2 label = (A=270 h=2.8 "Projected Volume (m3/ha)") w=4
    order = 0 to 280 by 20 minor = none color = black;

*** Horizontal Axis;
  axis3 label = (h=2.8 "Well-spaced Density (wsph) at MITD of 2.0 m")

    order = 0 to 1600 BY 200  minor = none w=4 color = black ;

*** Plotting Symbols;
symbol1  v=dot   h=1.5  l=1    i=splines   w=5   c=green; 

symbol2  v=dot   h=1.5  l=22   i=splines   w=5   c=red;

symbol3  v=none         l=1    i=join      w=5   c=black;

*** Specifying the graph;
title "   "; footnote "   ";  

filename graph "graph.cgm";

proc gplot data=graph; 

  plot y1*x = 1 y2*x = 2 / overlay vaxis=axis1 haxis=axis3 

     vref=0, 10, 80, 90, 100  href=700, 1200 chref=gray88 cvref=gray88; 

  plot2 y3*x = 3 / vaxis=axis2  ; 

run; quit;

� You may have to ensure that the CGM graphics filter is loaded into Office97.  It has not been part of the default installation.  Since administrative privileges are required you will need to get systems support to do this for you. 





1
5

